# Maintainer: Jacob Vincent Mink

pkgname=omawake-bin
_pkgname=${pkgname%-bin}
pkgver=0.0.1.rc.3
_upstream_ver=0.0.1-rc.3
pkgrel=1
pkgdesc='Configurable local wake-word daemon (pre-built binary)'
arch=('x86_64' 'aarch64')
url='https://github.com/jacob-vincent-mink/omawake'
license=('MIT')
depends=(
    'alsa-lib'
    'gcc-libs'
    'glibc'
)
optdepends=(
    'pipewire-audio: PipeWire audio support'
    'openvino: Intel runtime for an externally supplied OpenVINO provider bundle'
    'openvino-intel-gpu-plugin: Intel GPU device support for OpenVINO'
    'openvino-intel-npu-plugin: Intel NPU device support for OpenVINO'
    'cuda: NVIDIA CUDA libraries for an external CUDA runtime bundle'
    'cudnn: NVIDIA neural-network libraries for an external CUDA runtime bundle'
)
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
install="${pkgname}.install"
options=('!strip')

source_x86_64=("${_pkgname}-${_upstream_ver}-linux-x86_64.tar.xz::${url}/releases/download/v${_upstream_ver}/${_pkgname}-${_upstream_ver}-linux-x86_64.tar.xz")
source_aarch64=("${_pkgname}-${_upstream_ver}-linux-aarch64.tar.xz::${url}/releases/download/v${_upstream_ver}/${_pkgname}-${_upstream_ver}-linux-aarch64.tar.xz")

sha256sums_x86_64=('026ed87bcb44feac683f7087d611031b5ce01dbf2fe2f77e6838c9a27020f009')
sha256sums_aarch64=('c3d57b2e865eeb886660ced7bda6223b354975368162d637961c084c848fc5e6')

package() {
    local release_root="${srcdir}/${_pkgname}-${_upstream_ver}-linux-${CARCH}"

    install -Dm755 "${release_root}/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"

    install -Dm755 \
        "${release_root}/lib/libaudiocpp.so.0.1.0" \
        "${pkgdir}/usr/lib/${_pkgname}/libaudiocpp.so.0.1.0"
    ln -s libaudiocpp.so.0.1.0 \
        "${pkgdir}/usr/lib/${_pkgname}/libaudiocpp.so.0"
    ln -s libaudiocpp.so.0 \
        "${pkgdir}/usr/lib/${_pkgname}/libaudiocpp.so"

    install -Dm644 \
        "${release_root}/packaging/systemd/${_pkgname}.service" \
        "${pkgdir}/usr/lib/systemd/user/${_pkgname}.service"

    local document
    for document in \
        README.md \
        INSTALL.md \
        ACCELERATOR_SETUP.md \
        CHANGELOG.md \
        RELEASE_NOTES.md \
        DEMO.md \
        RUNTIME.md \
        config.example.toml; do
        install -Dm644 \
            "${release_root}/${document}" \
            "${pkgdir}/usr/share/doc/${pkgname}/${document}"
    done
    cp -r \
        "${release_root}/assets" \
        "${release_root}/benchmarks" \
        "${pkgdir}/usr/share/doc/${pkgname}/"

    install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
    cp -r \
        "${release_root}/licenses/." \
        "${pkgdir}/usr/share/licenses/${pkgname}/"
}
