# Maintainer: David Heinemeier Hansson <david@hey.com>

pkgname=omawrite
pkgver=0.1.0
pkgrel=1
pkgdesc='Dead-simple Markdown writing app built with Qt Quick'
arch=('x86_64' 'aarch64')
url='https://github.com/omacom-io/omawrite'
license=('MIT')
install='omawrite.install'
options=('!debug')
depends=(
  'hicolor-icon-theme'
  'qt6-base'
  'qt6-declarative'
  'ttf-ia-writer'
  'xdg-desktop-portal'
)
makedepends=(
  'gcc'
  'make'
  'qt6-base'
  'qt6-declarative'
)
source=("$pkgname-$pkgver.tar.gz::https://github.com/omacom-io/omawrite/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('4a78648b7da87ebf9d88e1b415e785fe9265089df9c837a6e499dfc0ffc71bd3')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./bin/build
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  install -Dm755 build/omawrite "$pkgdir/usr/bin/omawrite"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 pkgbuild/omawrite.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/omawrite.svg"
  install -Dm644 pkgbuild/omawrite.desktop "$pkgdir/usr/share/applications/omawrite.desktop"
}
