# Maintainer: David Heinemeier Hansson <david@hey.com>

pkgname=omatrack
pkgver=0.9.11
pkgrel=1
pkgdesc="Cross-format motorsport telemetry analysis workstation"
arch=('x86_64' 'aarch64')
url="https://github.com/tobi/omatrack"
license=('MIT')
depends=('qt6-base' 'qt6-declarative' 'mpv' 'libyaml' 'gcc-libs' 'glibc' 'hicolor-icon-theme')
makedepends=('cmake' 'ninja' 'rust')
options=('!debug' '!lto')

_commit=122c59f3911289c7ae4b11ecb0d5992699b08d75
source=("omatrack-$_commit.tar.gz::$url/archive/$_commit.tar.gz")
sha256sums=('3a2d457cb7c85d62147d98f2896e2b157a20f40f88b5496ae56b236b3337209a')

prepare() {
  cd "omatrack-$_commit/third_party/motorsport-telemetry"

  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
  cd "omatrack-$_commit"

  cmake -B build -S . -G Ninja \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  cmake --build build
}

package() {
  cd "omatrack-$_commit"

  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
