# Maintainer: David Heinemeier Hansson <david@hey.com>

pkgname=omatrack
pkgver=1.8.6
pkgrel=1
pkgdesc="Cross-format motorsport telemetry analysis workstation"
arch=('x86_64' 'aarch64')
url="https://github.com/tobi/omatrack"
license=('MIT')
depends=('qt6-base' 'qt6-declarative' 'mpv' 'libyaml' 'gcc-libs' 'glibc' 'hicolor-icon-theme')
makedepends=('cmake' 'ninja' 'rust')
options=('!debug' '!lto')

_commit=cd3fcdda3f8e15fda73288f6cf3803164138a7e4
source=("omatrack-$_commit.tar.gz::$url/archive/$_commit.tar.gz")
sha256sums=('6beb5703fe0b08a3bb99409581246498300f5cd91195239da00b91123681b8a3')

prepare() {
  cd "omatrack-$_commit/third_party/motorsport-telemetry"

  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
  cd "omatrack-$_commit"

  cmake -B build -S . -G Ninja \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  cmake --build build
}

package() {
  cd "omatrack-$_commit"

  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
