Add Meeting Recorder

pkgbuilds/omarchy-meeting-recorder-bin/.omarchy/package.json

@@ -0,0 +1,11 @@
+{
+  "source": "local",
+  "min_release_age": "24h",
+  "upstream": {
+    "github": "jankeesvw/omarchy-meeting-recorder",
+    "digests": true,
+    "assets": {
+      "x86_64": "omarchy-meeting-recorder-{pkgver}-x86_64-linux.tar.gz"
+    }
+  }
+}

pkgbuilds/omarchy-meeting-recorder-bin/PKGBUILD

@@ -0,0 +1,31 @@
+# Maintainer: Jankees van Woezik <mail@jankeesvw.com>
+
+pkgname=omarchy-meeting-recorder-bin
+_name=omarchy-meeting-recorder
+pkgver=1.0.2
+pkgrel=1
+pkgdesc="Meeting Recorder for Omarchy: record the mic and the computer audio, transcribed on your own machine with speakers, chapters and a player"
+arch=('x86_64')
+url="https://github.com/jankeesvw/omarchy-meeting-recorder"
+license=('MIT')
+depends=('gtk4' 'libadwaita' 'glib2' 'pango' 'cairo' 'graphene' 'libgcc' 'libstdc++' 'glibc' 'libpulse' 'ffmpeg')
+optdepends=('quickshell: the bar widget, part of every Omarchy install'
+            'perl-file-mimeinfo: open .meeting-recorder files with xdg-open, not only from Nautilus')
+provides=("$_name")
+conflicts=("$_name")
+install="$_name.install"
+options=('!debug')
+source_x86_64=("$url/releases/download/v$pkgver/$_name-$pkgver-x86_64-linux.tar.gz")
+sha256sums_x86_64=('78746ecc90366f12f308801637b98fc5e5b844bb28ba413e50ed3efe5c24079f')
+
+package() {
+  cd "$_name-$pkgver"
+  install -Dm755 "$_name" "$pkgdir/usr/bin/$_name"
+  install -Dm644 "data/$_name.desktop" "$pkgdir/usr/share/applications/$_name.desktop"
+  install -Dm644 "data/$_name.xml" "$pkgdir/usr/share/mime/packages/$_name.xml"
+  # The bar widget, to link into ~/.config/omarchy/plugins (see the install message).
+  install -Dm644 plugin/manifest.json "$pkgdir/usr/share/$_name/plugin/manifest.json"
+  install -Dm644 plugin/Widget.qml "$pkgdir/usr/share/$_name/plugin/Widget.qml"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
+}

pkgbuilds/omarchy-meeting-recorder-bin/omarchy-meeting-recorder.install

@@ -0,0 +1,22 @@
+post_install() {
+  cat <<'MSG'
+Meeting Recorder is installed; open it from the launcher.
+
+The first time you open it, it offers to put its widget in the bar
+(a live waveform while you record).
+
+Optional, per user:
+
+  A floating window, in ~/.config/hypr (Omarchy Quattro, Lua):
+    o.window("^com\\.jankeesvw\\.OmarchyMeetingRecorder$", { float = true })
+    o.window("^com\\.jankeesvw\\.OmarchyMeetingRecorder$", { size = { 480, 700 } })
+    o.window("^com\\.jankeesvw\\.OmarchyMeetingRecorder$", { center = true })
+
+The speech model (about 1.6 GB) is downloaded on first use, or taken from
+voxtype when it already has it.
+MSG
+}
+
+post_upgrade() {
+  :
+}