Merge pull request #142 from axelfontaine/dbxcli-bin

Add dbxcli-bin from AUR
2026-08-13 14:52:56 +02:00
parent 437f66df41 b4536eb011
commit 143a1697b0
3 changed files with 85 additions and 0 deletions
@@ -0,0 +1,5 @@
+[dbxcli-bin]
+source = "github"
+github = "dropbox/dbxcli"
+use_latest_release = true
+prefix = "v"
@@ -0,0 +1,4 @@
+{
+  "source": "aur",
+  "upstream_commit": "8fdd8f24e86252c0b67c4efe1a7ba58d439cfbd4"
+}
@@ -0,0 +1,76 @@
+# Maintainer:  Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
+
+_pkgname="dbxcli"
+pkgname="${_pkgname}-bin"
+pkgver=3.7.0
+pkgrel=1
+pkgdesc="A command line client for Dropbox built using the Go SDK"
+arch=(
+  'aarch64'
+  'armv7h'
+  'x86_64'
+)
+url="https://github.com/dropbox/${_pkgname}"
+license=(
+  'Apache-2.0'
+)
+depends=(
+  'glibc'
+)
+provides=(
+  "${_pkgname}"
+)
+conflicts=(
+  "${_pkgname}"
+)
+_pkgsrc="${url##*/}-${pkgver}"
+source_aarch64=(
+  "${url}/releases/download/v${pkgver}/${_pkgname}_${pkgver}_linux_arm64.tar.gz"
+)
+source_armv7h=(
+  "${url}/releases/download/v${pkgver}/${_pkgname}_${pkgver}_linux_arm.tar.gz"
+)
+source_x86_64=(
+  "${url}/releases/download/v${pkgver}/${_pkgname}_${pkgver}_linux_amd64.tar.gz"
+)
+sha256sums_aarch64=('9fb35971a4b050065e7adea3ca2315e4bff190110e96049aa6a160f2b65a48bc')
+sha256sums_armv7h=('5053dac6a5a2d7944246d4ccec1a569913d3bf5b355e2f78c09102354a3a6e8a')
+sha256sums_x86_64=('e296e32a4125be8c570b1640e8181d1d65ee09c8568a3528180340f3e87bb072')
+
+prepare() {
+  local source_array="source_${CARCH}[0]"
+  local source_url="${!source_array}"
+  local source_artifact="${source_url##*/}"
+
+  cd "${srcdir}/${source_artifact%.tar*}"
+  chmod +x ./"${_pkgname}"
+  mkdir -p "completions"
+}
+
+build() {
+  local source_array="source_${CARCH}[0]"
+  local source_url="${!source_array}"
+  local source_artifact="${source_url##*/}"
+
+  cd "${srcdir}/${source_artifact%.tar*}"
+  for _sh in bash fish powershell zsh; do
+    ./"${_pkgname}" completion "${_sh}" > "completions/${_pkgname}.${_sh}"
+  done
+} 
+
+package() {
+  local source_array="source_${CARCH}[0]"
+  local source_url="${!source_array}"
+  local source_artifact="${source_url##*/}"
+
+  cd "${srcdir}/${source_artifact%.tar*}"
+  install -vDm755 "${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
+  install -vDm644 "README.md"   "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
+  install -vDm644 "LICENSE"     "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
+
+  cd "completions"
+  install -vDm644 "${_pkgname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${_pkgname}"
+  install -vDm644 "${_pkgname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${_pkgname}.fish"
+  install -vDm644 "${_pkgname}.powershell" "${pkgdir}/usr/share/powershell/Completions/${_pkgname}.ps1"
+  install -vDm644 "${_pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${_pkgname}"
+}