Create shared / fast track for certain packages

2026-01-10 20:18:35 -05:00
1 parent 1dfa83863d
commit 45a356eb70
@@ -0,0 +1,24 @@
+pkgbase = cursor-bin
+	pkgdesc = AI-first coding environment
+	pkgver = 2.3.34
+	pkgrel = 1
+	url = https://www.cursor.com
+	arch = x86_64
+	license = LicenseRef-Cursor_EULA
+	depends = xdg-utils
+	depends = ripgrep
+	depends = electron37
+	depends = nodejs
+	depends = gcc-libs
+	depends = hicolor-icon-theme
+	depends = libxkbfile
+	noextract = cursor_2.3.34_amd64.deb
+	options = !strip
+	source = https://downloads.cursor.com/production/643ba67cd252e2888e296dd0cf34a0c5d7625b96/linux/x64/deb/amd64/deb/cursor_2.3.34_amd64.deb
+	source = https://gitlab.archlinux.org/archlinux/packaging/packages/code/-/raw/main/code.sh
+	source = rg.sh
+	sha512sums = deec916e163ef74130fedbc2bdc128cdf4cf10e833bb75f024fca7495ebcf05b8ae81197c161b5fe6d70cb307680bef0fbfbbc744b21f77c58124aa3a084a745
+	sha512sums = 937299c6cb6be2f8d25f7dbc95cf77423875c5f8353b8bd6cd7cc8e5603cbf8405b14dbf8bd615db2e3b36ed680fc8e1909410815f7f8587b7267a699e00ab37
+	sha512sums = e79fe7659f59d1ae02fc68816399bfd31587315df6cdb6ccf1d0ca76f7cdc692c2a42b30591c0091147bd97ef14b1c7745dc26bd7cb3ea6bba45698e5044fa2a
+
+pkgname = cursor-bin
@@ -0,0 +1,20 @@
+
+cursor-0.37.1.AppImage
+
+cursor-bin-0.37.1-1-x86_64.pkg.tar.zst
+
+pkg/cursor-bin/.BUILDINFO
+
+pkg/cursor-bin/.MTREE
+
+pkg/cursor-bin/.PKGINFO
+
+pkg/cursor-bin/opt/cursor-bin/cursor-bin.AppImage
+
+pkg/cursor-bin/usr/bin/cursor
+
+pkg/cursor-bin/usr/share/applications/cursor.desktop
+
+pkg/cursor-bin/usr/share/icons/hicolor/512x512/apps/cursor.png
+
+src/cursor.png
@@ -0,0 +1,36 @@
+# Maintainer: Gunther Schulz <dev@guntherschulz.de>
+
+pkgname=cursor-bin
+pkgver=2.3.34
+pkgrel=1
+pkgdesc='AI-first coding environment'
+arch=('x86_64')
+url="https://www.cursor.com"
+license=('LicenseRef-Cursor_EULA')
+_electron=electron37
+depends=(xdg-utils ripgrep $_electron nodejs
+  'gcc-libs' 'hicolor-icon-theme' 'libxkbfile')
+options=(!strip) # Don't break ext of VSCode
+_commit=643ba67cd252e2888e296dd0cf34a0c5d7625b96
+source=("https://downloads.cursor.com/production/${_commit}/linux/x64/deb/amd64/deb/cursor_${pkgver}_amd64.deb"
+https://gitlab.archlinux.org/archlinux/packaging/packages/code/-/raw/main/code.sh rg.sh)
+sha512sums=('SKIP'
+  '937299c6cb6be2f8d25f7dbc95cf77423875c5f8353b8bd6cd7cc8e5603cbf8405b14dbf8bd615db2e3b36ed680fc8e1909410815f7f8587b7267a699e00ab37'
+  'e79fe7659f59d1ae02fc68816399bfd31587315df6cdb6ccf1d0ca76f7cdc692c2a42b30591c0091147bd97ef14b1c7745dc26bd7cb3ea6bba45698e5044fa2a')
+sha512sums[0]=deec916e163ef74130fedbc2bdc128cdf4cf10e833bb75f024fca7495ebcf05b8ae81197c161b5fe6d70cb307680bef0fbfbbc744b21f77c58124aa3a084a745
+noextract=(cursor_${pkgver}_amd64.deb) # avoid double tarball
+_app=usr/share/cursor/resources/app
+package() {
+  # Exclude electron
+  bsdtar -xOf ${noextract[0]} data.tar.xz | tar -xJf - -C "$pkgdir" \
+    --exclude 'usr/share/cursor/[^r]*' --exclude 'usr/share/cursor/*.pak'
+  cd "$pkgdir"
+  mv usr/share/zsh/{vendor-completions,site-functions}
+  ln -sf /usr/bin/node ${_app}/resources/helpers/node
+  install -Dm755 "${srcdir}/rg.sh" ${_app}/node_modules/@vscode/ripgrep/bin/rg
+  ln -sf /usr/bin/xdg-open ${_app}/node_modules/open/xdg-open
+  sed -e "s|code-flags|cursor-flags|" -e "s|/usr/lib/code|/${_app}|" -e "s|/usr/lib/code/code.mjs|--app=/${_app}|" \
+    -e "s|name=electron|name=${_electron}|" "${srcdir}"/code.sh | install -Dm755 /dev/stdin "${pkgdir}"/usr/share/cursor/cursor
+  install -d "$pkgdir"/usr/bin
+  ln -sf /usr/share/cursor/cursor "$pkgdir"/usr/bin/cursor
+}
@@ -0,0 +1,2 @@
+#!/bin/bash
+exec /usr/bin/rg "${@/--cursor-ignore/--ignore-file}"