Add the umu-launcher needed for Battle.net installer

build/packages/edge.packages

@@ -31,6 +31,7 @@ python-terminaltexteffects
 ttf-ia-writer
 typora
 tzupdate
+umu-launcher
 ufw-docker
 walker
 xdg-terminal-exec

pkgbuilds/edge/umu-launcher/PKGBUILD

@@ -0,0 +1,81 @@
+# Maintainer: loathingkernel <loathingkernel _a_ gmail _d_ com>
+
+pkgname=umu-launcher
+pkgver=1.1.3
+pkgrel=1
+pkgdesc="This is the Unified Launcher for Windows Games on Linux, to run Proton with fixes outside of Steam"
+arch=('x86_64')
+url="https://github.com/Open-Wine-Components/umu-launcher"
+license=('GPL-3.0-only')
+depends=(
+  # steam
+  bash
+  desktop-file-utils
+  diffutils
+  hicolor-icon-theme
+  curl
+  dbus
+  freetype2
+  gdk-pixbuf2
+  ttf-font
+  zenity
+  lsb-release
+  nss
+  usbutils
+  xorg-xrandr
+  vulkan-driver
+  vulkan-icd-loader
+  lsof
+  python
+  xdg-user-dirs
+  glibc
+  libxcrypt
+  libxcrypt-compat
+  gcc-libs
+  # umu
+  python-xlib
+  python-filelock
+)
+depends_x86_64=(
+  lib32-glibc
+  lib32-libxcrypt
+  lib32-libxcrypt-compat
+  lib32-libgl
+  lib32-gcc-libs
+  lib32-libx11
+  lib32-libxss
+  lib32-alsa-plugins
+  lib32-libgpg-error
+  lib32-nss
+  lib32-vulkan-driver
+  lib32-vulkan-icd-loader
+)
+makedepends=(
+  git
+  scdoc
+  python-build
+  python-installer
+  python-hatchling
+)
+install=
+_origin="https://github.com/Open-Wine-Components/umu-launcher.git"
+source=(
+  "git+$_origin#tag=$pkgver"
+)
+
+prepare() {
+  cd "$srcdir"/umu-launcher
+}
+
+build() {
+  cd "$srcdir"/umu-launcher
+  ./configure.sh --prefix=/usr
+  make
+}
+
+package() {
+  cd "$srcdir"/umu-launcher
+  make DESTDIR="$pkgdir" install
+}
+
+sha256sums=('14561329686b0fe4b9950841c50bf67b9419384dc25b0449064cece467a03209')