Add owe, the wallpaper engine for video backgrounds

The OWE engine owns desktop video backgrounds in omarchy#12429. This
recipe is imported from the owe AUR package and watches the vX.Y.Z tags
on omacom/owe. It builds for x86_64 and aarch64.

0.1.1 is the first release that plays the wallpaper audio track.

pkgbuilds/owe/.omarchy/package.json

@@ -0,0 +1,14 @@
+{
+  "source": "local",
+  "release_ring": "fast",
+  "upstream": {
+    "watch": {
+      "github": "omacom/owe",
+      "pattern": "v(?P<version>[0-9]+(?:\\.[0-9]+)*)"
+    }
+  },
+  "origin": {
+    "aur": "owe",
+    "commit": "884100f82cf2940e4c1ef50dff39a99e37e9895e"
+  }
+}

pkgbuilds/owe/PKGBUILD

@@ -0,0 +1,34 @@
+# Maintainer: owe contributors
+pkgname=owe
+pkgver=0.1.1
+pkgrel=1
+pkgdesc="High-performance wallpaper engine for Omarchy (mp4, gif, stills)"
+arch=('x86_64' 'aarch64')
+url="https://github.com/omacom/owe"
+license=('MIT')
+depends=('mpv' 'ffmpeg' 'wayland' 'libglvnd' 'libepoxy' 'systemd-libs' 'socat')
+makedepends=('meson' 'ninja' 'gcc' 'pkgconf' 'wayland-protocols')
+checkdepends=('python')
+optdepends=('intel-media-driver: VAAPI hardware decode on Intel GPUs'
+            'libva-mesa-driver: VAAPI hardware decode on AMD GPUs')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/omacom/owe/archive/refs/tags/v$pkgver.tar.gz")
+sha256sums=('64dc47e510973983bcbe37234ce2cf72ce1abbf3265aa54d3bc1c22da3ffa8c5')
+
+build() {
+  meson setup build "$srcdir/owe-$pkgver" -Dbuildtype=release -Dprefix=/usr
+  ninja -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -C build install
+  install -d "$pkgdir/usr/lib/systemd/user"
+  sed 's|%h/.local/bin/owed|/usr/bin/owed|' "$srcdir/owe-$pkgver/systemd/owed.service" \
+    >"$pkgdir/usr/lib/systemd/user/owed.service"
+  install -Dm755 "$srcdir/owe-$pkgver/hooks/owe-idle" "$pkgdir/usr/bin/owe-idle"
+  install -Dm644 "$srcdir/owe-$pkgver/hooks/theme-set.d/10-owe-sync" "$pkgdir/usr/share/owe/10-owe-sync"
+  install -Dm644 "$srcdir/owe-$pkgver/config/config.toml" "$pkgdir/usr/share/doc/$pkgname/config.toml.example"
+}