# Maintainer: David Heinemeier Hansson <david@hey.com>

pkgname=monologue
pkgver=0.3.0
pkgrel=1
pkgdesc='A simple, theme-synced webcam recorder for Omarchy'
arch=('x86_64' 'aarch64')
url='https://github.com/omacom/monologue'
license=('MIT')
install='monologue.install'
options=('!debug')
depends=(
  'ffmpeg'
  'hicolor-icon-theme'
  'libpulse'
  'qt6-base'
  'qt6-declarative'
  'qt6-multimedia>=6.8'
  'xdg-desktop-portal'
)
makedepends=('gcc' 'make' 'pkgconf')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('03761403736a600f9c2b6c53b57fbe95e6c79bb42758412d9e43d91c0ffd6999')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./bin/build
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  install -Dm755 build/monologue "$pkgdir/usr/bin/monologue"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 pkgbuild/monologue.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/monologue.svg"
  install -Dm644 pkgbuild/monologue.desktop "$pkgdir/usr/share/applications/monologue.desktop"
}