# Maintainer: Ryan Hughes <ryan@omarchy.org>

pkgname=omarchy-zsh
pkgver=1.5.0
pkgrel=2
pkgdesc="Omarchy shell configuration for Zsh"
arch=('any')
url="https://github.com/omacom-io/omarchy-zsh"
license=('MIT')
depends=('zsh' 'eza' 'mise' 'zoxide' 'starship' 'fzf' 'fd' 'bat' 'zsh-syntax-highlighting')
options=('!debug')
install=omarchy-zsh.install
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
        "omadots.tar.gz::https://github.com/omacom-io/omadots/archive/refs/heads/master.tar.gz")
sha256sums=('e481aad290692a2a4560ee340dcd2c9839b85ab1ed05a8d482793cb219ce8313'
            'SKIP')

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # Install shared shell config from omadots (aliases, functions, envs, inits, inputrc)
  install -dm755 "${pkgdir}/usr/share/${pkgname}/shell"
  cp -r "${srcdir}/omadots-master/config/shell/." "${pkgdir}/usr/share/${pkgname}/shell/"

  # Rewrite paths to source from installed package location instead of user config
  find "${pkgdir}/usr/share/${pkgname}/shell" -type f -exec \
    sed -i \
      -e 's|"\$HOME"/\.config/shell|/usr/share/omarchy-zsh/shell|g' \
      -e 's|\$HOME/\.config/shell|/usr/share/omarchy-zsh/shell|g' \
      {} +

  # Install zsh-specific zoptions from omarchy-zsh
  cp shell/zoptions "${pkgdir}/usr/share/${pkgname}/shell/"

  # Install zsh completions to the standard site-functions dir so they
  # autoload via the default fpath. compinit is invoked from zoptions.
  install -dm755 "${pkgdir}/usr/share/zsh/site-functions"
  cp shell/completions/* "${pkgdir}/usr/share/zsh/site-functions/"

  # Install templates and documentation
  install -dm755 "${pkgdir}/usr/share/${pkgname}"
  cp -r templates LICENSE README.md "${pkgdir}/usr/share/${pkgname}/"

  # Install setup script
  install -Dm755 bin/omarchy-setup-zsh "${pkgdir}/usr/bin/omarchy-setup-zsh"
}