# Maintainer: David Heinemeier Hansson <david@hey.com>

pkgname=omawrite
pkgver=0.2.3
pkgrel=1
pkgdesc='Dead-simple Markdown writing app built with Qt Quick'
arch=('x86_64' 'aarch64')
url='https://github.com/omacom-io/omawrite'
license=('MIT' 'OFL-1.1')
install='omawrite.install'
options=('!debug')
depends=(
  'hicolor-icon-theme'
  'qt6-base'
  'qt6-declarative'
  'xdg-desktop-portal'
)
makedepends=(
  'gcc'
  'make'
  'qt6-base'
  'qt6-declarative'
)
source=("$pkgname-$pkgver.tar.gz::https://github.com/omacom-io/omawrite/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('b2ab4852ea8f7f2c0e3ccd05e05892071a5b8e7cf1f6fb6051f491bb84cdca3d')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./bin/build
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  install -Dm755 build/omawrite "$pkgdir/usr/bin/omawrite"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 fonts/OFL.txt "$pkgdir/usr/share/licenses/$pkgname/OFL.txt"
  install -Dm644 pkgbuild/omawrite.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/omawrite.svg"
  install -Dm644 pkgbuild/omawrite.desktop "$pkgdir/usr/share/applications/omawrite.desktop"
}