# Maintainer: David Heinemeier Hansson <david@hey.com>

# Build a prebuilt release; Omarchy seeds it into the user's Hermes checkout
# so the upstream updater can rebuild and relaunch it in place.

pkgname=hermes-desktop
pkgver=2026.9.7
pkgrel=4
pkgdesc='Native desktop shell for Hermes Agent'
arch=('x86_64')
url='https://github.com/NousResearch/hermes-agent'
license=('MIT')

depends=(
  'alsa-lib'
  'at-spi2-core'
  'cairo'
  'dbus'
  'expat'
  'curl'
  'gcc'
  'gdk-pixbuf2'
  'git'
  'glib2'
  'glibc'
  'gtk3'
  'hicolor-icon-theme'
  'libcups'
  'libdrm'
  'libglvnd'
  'libnotify'
  'libsecret'
  'libx11'
  'libxcb'
  'libxcomposite'
  'libxdamage'
  'libxext'
  'libxfixes'
  'libxkbcommon'
  'libxrandr'
  'make'
  'mesa'
  'nodejs'
  'npm'
  'nspr'
  'nss'
  'pango'
  'python'
  'systemd-libs'
  'util-linux'
  'xdg-utils'
)

optdepends=('omarchy: sets up the user installation for in-app updates')

# The build runs the repo's own npm workspace install, which fetches Electron
# and rebuilds node-pty against it.
makedepends=('imagemagick')

# Electron bundles prebuilt binaries that stripping corrupts.
options=('!strip' '!debug')

# The tag's commit. apps/desktop/scripts/write-build-stamp.mjs pins the app's
# first-launch bootstrap to a Hermes commit, and resolves it from $GITHUB_SHA
# before falling back to `git rev-parse`. That fallback is wrong here: makepkg
# builds inside this repository, so git ascends out of srcdir and stamps the
# app with an omarchy-pkgs commit that means nothing upstream.
_commit=2237be355906fbe6065ce1815711eee52b2d646e

_srcdir="hermes-agent-${pkgver}"
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
        'hermes-desktop.sh'
        'hermes-desktop.desktop'
        'hermes-desktop.png'
        'runtime.patch'
        'runtime-test.py')
sha256sums=('907c2a72db1c5dd637ea8eeae97f4cb5b32cef615c17258f6b190924ec5bf688'
            'f7519cee8e0f64d9c4859dc1d2eb7e223f94ab22ab522a66cbaada05944ef71b'
            '3ef685bfcf366776b025d26c37d32854d8d4aa2023b2bd07c8e08b001ef1e8c4'
            'd60d164e24fdcf6532133b8ea43c77a201e4b9e9dbc396187b58d51d8590ef52'
            '9d5015d1be762a901f8f64319981ae862e9852fa5cb9a22a2ba1e691f90430a2'
            '84373e503dc5ba5ce099c57150f281247dda941b477c0cd679c50fe0d3a0bbb1')

build() {
  cd "${srcdir}/${_srcdir}"

  export GITHUB_SHA="${_commit}"
  export GITHUB_REF_NAME="main"

  # The desktop workspace resolves against the repo root, so the install has to
  # happen there rather than in apps/desktop.
  npm ci

  cd apps/desktop
  npm run pack
}

check() {
  python "${srcdir}/runtime-test.py" "${srcdir}/${_srcdir}" "${srcdir}/runtime.patch" "${srcdir}/hermes-desktop.sh"
}

package() {
  cd "${srcdir}/${_srcdir}/apps/desktop/release/linux-unpacked"

  install -dm755 "${pkgdir}/opt/${pkgname}"
  cp -a . "${pkgdir}/opt/${pkgname}/"

  install -Dm755 "${srcdir}/hermes-desktop.sh" "${pkgdir}/usr/bin/${pkgname}"

  install -Dm644 "${srcdir}/${_srcdir}/scripts/install.sh" \
    "${pkgdir}/usr/share/${pkgname}/install.sh"
  # Omarchy's installer still requires this patch. The release includes the
  # fix, so the installer recognizes it through its reverse-apply check.
  install -Dm644 "${srcdir}/runtime.patch" "${pkgdir}/usr/share/${pkgname}/runtime.patch"

  install -Dm644 "${srcdir}/hermes-desktop.desktop" \
    "${pkgdir}/usr/share/applications/${pkgname}.desktop"

  install -Dm644 "${srcdir}/hermes-desktop.png" \
    "${pkgdir}/usr/share/icons/hicolor/1024x1024/apps/${pkgname}.png"
  local size
  for size in 512 256 128 64 48; do
    magick "${srcdir}/hermes-desktop.png" -resize "${size}x${size}" "${srcdir}/icon-${size}.png"
    install -Dm644 "${srcdir}/icon-${size}.png" \
      "${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/${pkgname}.png"
  done

  install -Dm644 "${srcdir}/${_srcdir}/LICENSE" \
    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -Dm644 "${pkgdir}/opt/${pkgname}/LICENSE.electron.txt" \
    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.electron.txt"

  # The launcher requires the namespace sandbox on the target host.
  chmod 0755 "${pkgdir}/opt/${pkgname}/chrome-sandbox"
}