# Maintainer: David Heinemeier Hansson <david@hey.com>

pkgname=hype
pkgver=0.4.3
pkgrel=1
pkgdesc='Simple Markdown presentations with a visual slide editor'
arch=('x86_64' 'aarch64')
url='https://github.com/omacom/hype'
license=('MIT')
install='hype.install'
options=('!debug')
depends=(
  'ffmpeg'
  'hicolor-icon-theme'
  'qt6-base>=6.9'
  'qt6-declarative>=6.9'
  'qt6-multimedia>=6.9'
  'qt6-imageformats'
  'qt6-svg'
  'source-highlight'
  'zlib'
  'libwebp'
  'xdg-desktop-portal'
)
makedepends=('gcc' 'make')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('860a86764dced7c8e005d56c1533013fa8ad9144aaf2880e9b38e868640581a8')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./bin/build
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  install -Dm755 build/hype "$pkgdir/usr/bin/hype"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 pkgbuild/hype.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/hype.svg"
  install -Dm644 pkgbuild/hype.desktop "$pkgdir/usr/share/applications/hype.desktop"
  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}