# Maintainer: Dan Wahlin <dwahlin@gmail.com>

pkgname=learn-omarchy
pkgver=0.2.5
pkgrel=2
pkgdesc="Interactive, theme-aware courses for learning Omarchy"
arch=('any')
url="https://github.com/DanWahlin/learn-omarchy"
license=('MIT' 'CC-BY-4.0' 'CC0-1.0')
depends=(
  'bash' 'coreutils' 'sudo' 'hyprland' 'mpv' 'nodejs>=22.6' 'omarchy'
  'quickshell>=0.3' 'qt6-declarative' 'qt6-multimedia' 'qt6-multimedia-ffmpeg' 'xdg-utils'
  'xdg-terminal-exec' 'nautilus'
  'ttf-liberation' 'noto-fonts-emoji'
  'grim' 'slurp' 'gpu-screen-recorder' 'util-linux' 'ffmpeg'
)
makedepends=('make')
optdepends=(
  'btop: activity-monitor practice'
  'tesseract: OCR practice'
  'tesseract-data-eng: English OCR sample recognition'
  'zbar: QR recognition (zbarimg)'
  'qrencode: QR sample creation'
  'voxtype: optional dictation practice'
)
options=('!strip')
source=("$pkgname-$pkgver.tar.gz::$url/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('b9a18b38b8600506870ca24d4ca75176c045600ccb696f7597dc4f992031bafd')

package() {
  cd "$srcdir/$pkgname-$pkgver"
  node tools/prepare-release.mjs --check .
  make DESTDIR="$pkgdir" PREFIX=/usr install
}