# Maintainer: David Heinemeier Hansson <david@hey.com>

pkgname=signed
pkgver=0.1.0
pkgrel=1
pkgdesc='Sign PDFs and fill them in with text and dates'
arch=('x86_64' 'aarch64')
url='https://github.com/omacom/signed'
license=('MIT')
install='signed.install'
options=('!debug')
depends=(
  'hicolor-icon-theme'
  'noto-fonts'
  'poppler-qt6'
  'qpdf'
  'qt6-base'
  'qt6-declarative'
  'qt6-wayland'
  'xdg-desktop-portal'
)
makedepends=('gcc' 'make')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('f2d9b59c5a2c9ca4fd7b6d4814ae26a3b2036cdb6685d35c71452f2486fd08e2')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./bin/build
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  install -Dm755 build/signed "$pkgdir/usr/bin/signed"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 pkgbuild/signed.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/signed.svg"
  install -Dm644 pkgbuild/signed.desktop "$pkgdir/usr/share/applications/signed.desktop"
  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}