# Maintainer: Florian Moser <arch@famoser.ch>

pkgname=symfony-cli
pkgrel=1
pkgver=5.22.0
pkgdesc="The Symfony client helps developers create and manage Symfony applications."
url="https://symfony.com/"
arch=('x86_64' 'aarch64')
license=('AGPL3')
depends=('glibc')
makedepends=('go')
provides=('symfony-cli')
conflicts=('symfony-cli')
source=("$pkgname-$pkgver.tar.gz::https://github.com/symfony-cli/symfony-cli/releases/download/v${pkgver}/symfony-cli-${pkgver}.tar.gz")
sha256sums=('c767b60b9a68c17ea170355f2d148cba21969f50770a6e2981e35c8c726e5355')
noextract=("$pkgname-$pkgver.tar.gz")

prepare() {
  mkdir "$pkgname-$pkgver"
  bsdtar -xf "$pkgname-$pkgver.tar.gz" -C "$pkgname-$pkgver"
}

build() {
  cd "$pkgname-$pkgver"

  DATE=$(date -u +"%Y-%m-%dT%H:%M:%SZ")
  PKGVER=${pkgver}

  go mod download
  go build -trimpath -ldflags '-s -w -X main.channel=stable -X main.buildDate='"${DATE}"' -X main.version='"${PKGVER}"''
}

package() {
    install -D -m 755 "${srcdir}/${pkgname}-${pkgver}/symfony-cli" "${pkgdir}/usr/bin/symfony"
}