# Maintainer: Tobi Lütke <tobi@lutke.com>

pkgname=omasnap
pkgver=1.0.6
pkgrel=1
pkgdesc="Native Wayland screenshot and annotation overlay for Hyprland"
arch=('x86_64')
url="https://github.com/tobi/omasnap"
license=('custom')
depends=(
  'grim'
  'hyprland'
  'layer-shell-qt'
  'qt6-base'
  'tesseract'
  'tesseract-data-eng'
  'wayland'
  'wl-clipboard'
)
makedepends=(
  'cmake'
  'ninja'
  'pkgconf'
  'wayland-protocols'
)
options=('!debug')

source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('7d25d6e2bcb4ddc1541382655fa2245980829c0f51a8d720b3e63fbee8142474')

build() {
  cmake -S "$pkgname-$pkgver" -B build -G Ninja \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  cmake --build build --parallel
}

check() {
  QT_QPA_PLATFORM=offscreen \
    ./build/omasnap-smoke "$srcdir/omasnap-smoke-output"
}

package() {
  cmake --install build --prefix "$pkgdir/usr"
  install -Dm644 "$pkgname-$pkgver/README.md" \
    "$pkgdir/usr/share/doc/$pkgname/README.md"
}