# Canonical recipe. scripts/package-source.sh fills the release source checksum.
# Maintainer: Tom Ballard (tcballard)
pkgname=omarchy-task-manager
pkgver=0.0.3
pkgrel=3
url='https://github.com/tcballard/omarchy-task-manager'
pkgdesc='Floating native task manager for Omarchy (preview)'
arch=('x86_64')
license=('MIT')
depends=('qt6-base' 'qt6-declarative' 'qt6-wayland' 'qt6-svg' 'hicolor-icon-theme' 'gcc-libs' 'glibc' 'glib2' 'systemd' 'coreutils')
optdepends=('gdb: live process core dumps' 'nvidia-utils: NVIDIA device telemetry')
makedepends=('cmake' 'ninja' 'rust' 'cargo')
checkdepends=('python' 'desktop-file-utils')
source=("$url/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz"
        "pause-resume-test.patch"
        "worker-shutdown.patch")
sha256sums=('cc3e24a0bb8fad2b7ce0d4fb780aa774d32b53b8de924b488b55674bdb936c85'
            'ce191fc8dc7e4f7018193aa4982d58fd463f66b37e3129b3acce46b7a1c9a89e'
            '1142aaedf8739bf2ed1cb823a03ed7e406d7ff59d7dfb72748815cc81cfda96b')

# Backport upstream PR #11 (sample observation) and PR #12 (worker shutdown).
prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -Np1 -i "$srcdir/pause-resume-test.patch"
  patch -Np1 -i "$srcdir/worker-shutdown.patch"
}

build() {
  cmake -S "$srcdir/$pkgname-$pkgver" -B build -G Ninja \
    -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_INSTALL_LIBDIR=lib
  cmake --build build
}

check() {
  cd "$srcdir/$pkgname-$pkgver"
  cargo test --locked
  ctest --test-dir "$srcdir/build" --output-on-failure
  desktop-file-validate packaging/io.github.tcballard.TaskManager.desktop
  python tests/protocol.py "$srcdir/build/omarchy-task-manager-core"
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}