# Maintainer: Jacob Vincent Mink

pkgname=omaspeak-bin
_pkgname=${pkgname%-bin}
pkgver=0.0.3
_upstream_ver=0.0.3
pkgrel=4
pkgdesc='Local-first text-to-speech application and daemon (pre-built binary)'
arch=('x86_64' 'aarch64')
url='https://github.com/jacob-vincent-mink/omaspeak'
license=('MIT' 'Apache-2.0' 'BSD-3-Clause')
depends=(
    'alsa-utils'
    'gcc-libs'
    'glibc'
)
optdepends=(
    'pipewire-audio: audio playback through pw-play'
    'openvino: Intel CPU acceleration runtime'
    'openvino-intel-gpu-plugin: Intel GPU device support for OpenVINO'
    'openvino-intel-npu-plugin: Intel NPU device support for OpenVINO'
    'cuda: NVIDIA CUDA libraries for an external CUDA runtime bundle'
    'cudnn: NVIDIA neural-network libraries for an external CUDA runtime bundle'
)
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
install="${pkgname}.install"
options=('!strip' '!debug')

source=('package-remove' 'remove-user-services.hook')
sha256sums=('f1b527448529b45fee2f96b4c0a19b11087377c0ac9f43842bab0d04fcfd3b9f'
            '9f1a0c2f5031fcd5905de77643a8727b792e07c582c09c2ba179f0714f118b20')

source_x86_64=("${_pkgname}-${_upstream_ver}-linux-x86_64.tar.xz::${url}/releases/download/v${_upstream_ver}/${_pkgname}-${_upstream_ver}-linux-x86_64.tar.xz")
source_aarch64=("${_pkgname}-${_upstream_ver}-linux-aarch64.tar.xz::${url}/releases/download/v${_upstream_ver}/${_pkgname}-${_upstream_ver}-linux-aarch64.tar.xz")

sha256sums_x86_64=('c72428bf6989582b5aa802f39e9390e4cacf26f7fbfacf76645118286c7d1ab2')
sha256sums_aarch64=('88fc4ea8c275b9d5b9d41602d32dbca77ee30de0fc7dcbc06ad0e819fd41545a')

package() {
    install -Dm755 "${srcdir}/package-remove" "${pkgdir}/usr/lib/${_pkgname}/package-remove"
    install -Dm644 "${srcdir}/remove-user-services.hook" \
        "${pkgdir}/usr/share/libalpm/hooks/30-${_pkgname}-remove-user-services.hook"

    local release_root="${srcdir}/${_pkgname}-${_upstream_ver}-linux-${CARCH}"

    install -Dm755 "${release_root}/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"

    install -Dm755 \
        "${release_root}/lib/libaudiocpp.so.0.1.0" \
        "${pkgdir}/usr/lib/${_pkgname}/libaudiocpp.so.0.1.0"
    ln -s libaudiocpp.so.0.1.0 \
        "${pkgdir}/usr/lib/${_pkgname}/libaudiocpp.so.0"
    ln -s libaudiocpp.so.0 \
        "${pkgdir}/usr/lib/${_pkgname}/libaudiocpp.so"

    install -Dm644 \
        "${release_root}/packaging/systemd/${_pkgname}.service" \
        "${pkgdir}/usr/lib/systemd/user/${_pkgname}.service"

    local document
    for document in \
        README.md \
        INSTALL.md \
        ACCELERATOR_SETUP.md \
        CHANGELOG.md \
        RELEASE_NOTES.md \
        DEMO.md \
        RUNTIME.md \
        config.example.toml; do
        install -Dm644 \
            "${release_root}/${document}" \
            "${pkgdir}/usr/share/doc/${pkgname}/${document}"
    done
    cp -r \
        "${release_root}/assets" \
        "${release_root}/benchmarks" \
        "${pkgdir}/usr/share/doc/${pkgname}/"

    install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
    cp -r \
        "${release_root}/licenses/." \
        "${pkgdir}/usr/share/licenses/${pkgname}/"
}