# Maintainer: David Heinemeier Hansson <david@hey.com>

pkgname=omatrack
pkgver=1.2.0
pkgrel=1
pkgdesc="Cross-format motorsport telemetry analysis workstation"
arch=('x86_64' 'aarch64')
url="https://github.com/tobi/omatrack"
license=('MIT')
depends=('qt6-base' 'qt6-declarative' 'mpv' 'libyaml' 'gcc-libs' 'glibc' 'hicolor-icon-theme')
makedepends=('cmake' 'ninja' 'rust')
options=('!debug' '!lto')

_commit=ebe7f4f6b05845a85a2b713f889e676442fd0e82
source=("omatrack-$_commit.tar.gz::$url/archive/$_commit.tar.gz")
sha256sums=('8e6c62de5f8c98239a84abe9696c83f1155bef12004ee2c028bd99d64b8263a4')

prepare() {
  cd "omatrack-$_commit/third_party/motorsport-telemetry"

  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
  cd "omatrack-$_commit"

  cmake -B build -S . -G Ninja \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  cmake --build build
}

package() {
  cd "omatrack-$_commit"

  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}