33 lines
1.5 KiB
Bash
33 lines
1.5 KiB
Bash
# Maintainer: Tobi Lütke <tobi@shopify.com>
|
|
|
|
pkgname=disktree-bin
|
|
_name=disktree
|
|
pkgver=0.11.0
|
|
pkgrel=1
|
|
pkgdesc="Disk space treemap for Omarchy: see what fills a disk by kind, mark what should go, and remove it"
|
|
arch=('x86_64' 'aarch64')
|
|
url="https://github.com/tobi/disktree"
|
|
license=('MIT')
|
|
depends=('glibc' 'libgcc' 'libxcb' 'libxkbcommon' 'libxkbcommon-x11' 'wayland' 'libglvnd' 'vulkan-icd-loader')
|
|
optdepends=('trash-cli: move to the trash with trash-put (gio or a built-in XDG trash otherwise)'
|
|
'git: changes, stashes and unpushed commits of a selected checkout')
|
|
provides=("$_name")
|
|
conflicts=("$_name")
|
|
options=('!debug')
|
|
source_x86_64=("$url/releases/download/v$pkgver/$_name-$pkgver-x86_64-linux.tar.gz")
|
|
source_aarch64=("$url/releases/download/v$pkgver/$_name-$pkgver-aarch64-linux.tar.gz")
|
|
sha256sums_x86_64=('7e75afa2283c8b4f9290d52eadbfc00d9f14c13aed2d224ccdf0f7826fcc05b2')
|
|
sha256sums_aarch64=('3c75f9c82069e40310c821357a52aee2f11a9c3e2b45452c9893dbf7cb5e454a')
|
|
|
|
package() {
|
|
cd "$_name-$pkgver-$CARCH-linux"
|
|
install -Dm755 "$_name" "$pkgdir/usr/bin/$_name"
|
|
install -dm755 "$pkgdir/usr/share/applications"
|
|
sed -e 's|@BINDIR@/||' -e "s|@VERSION@|$pkgver|" "$_name.desktop.in" \
|
|
> "$pkgdir/usr/share/applications/$_name.desktop"
|
|
chmod 644 "$pkgdir/usr/share/applications/$_name.desktop"
|
|
install -Dm644 "$_name.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/$_name.svg"
|
|
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
|
|
install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
|
|
}
|