David Heinemeier HanssonandClaude Opus 5
0433b2ac30
Both fixes we carried are upstream now, in the only two commits made since our pin: 43d4fa9 strips the crash relaunch environment and closes the info fd, and 28771c7 makes IpcHandler deregister through the registry it registered with rather than re-resolving its engine generation. Upstream reaches the IPC fix differently - IpcHandlerRegistry became a QObject held in a QPointer, where we kept a raw back-pointer cleared from ~IpcHandlerRegistry - but it covers the same two cases: a handler outliving its QML context, and a registry destroyed before its handlers. Built clean without the patches at 0.3.0.r20.g28771c7-1. Co-Authored-By: Claude Opus 5 (1M context) <noreply@anthropic.com>
68 lines
1.5 KiB
Bash
68 lines
1.5 KiB
Bash
# Maintainer: Entailz <entail-wraps0r at icloud dot com>
|
|
|
|
_pkgname=quickshell
|
|
pkgname="$_pkgname-git"
|
|
pkgver=0.3.0.r20.g28771c7
|
|
pkgrel=1
|
|
pkgdesc='Flexible toolkit for making desktop shells with QtQuick'
|
|
arch=(x86_64 aarch64)
|
|
url='https://git.outfoxxed.me/quickshell/quickshell'
|
|
options=(!strip)
|
|
license=('LGPL-3.0-only')
|
|
depends=(
|
|
'qt6-declarative'
|
|
'qt6-base'
|
|
'jemalloc'
|
|
'qt6-svg'
|
|
'libpipewire'
|
|
'libxcb'
|
|
'wayland'
|
|
'libdrm'
|
|
'mesa'
|
|
'cpptrace'
|
|
'vulkan-headers'
|
|
'polkit'
|
|
)
|
|
makedepends=(
|
|
'spirv-tools'
|
|
'qt6-shadertools'
|
|
'wayland'
|
|
'wayland-protocols'
|
|
'cli11'
|
|
'ninja'
|
|
'cmake'
|
|
'git'
|
|
)
|
|
provides=("$_pkgname")
|
|
conflicts=("$_pkgname")
|
|
|
|
_pkgsrc="$_pkgname"
|
|
source=("$_pkgsrc"::"git+$url.git#commit=28771c7c74b42e20afca0b1b63980cb46515537c"
|
|
quickshell-check.hook)
|
|
sha256sums=('SKIP'
|
|
'8543e21aeaaa5441b73a679160e7601a957f16c433e8d6bd9257e80bd0e94083')
|
|
|
|
pkgver() {
|
|
cd "$_pkgsrc"
|
|
git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
|
|
| sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
|
|
}
|
|
|
|
build() {
|
|
cd "$_pkgname"
|
|
cmake -GNinja -B build \
|
|
-DCMAKE_BUILD_TYPE="RelWithDebInfo" \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DDISTRIBUTOR="AUR (package: quickshell-git)" \
|
|
-DINSTALL_QML_PREFIX=lib/qt6/qml
|
|
|
|
cmake --build build
|
|
}
|
|
|
|
package() {
|
|
install -Dm644 "quickshell-check.hook" -t "$pkgdir/usr/share/libalpm/hooks"
|
|
cd "$_pkgname"
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$_pkgname"
|
|
}
|