David Heinemeier HanssonandClaude Fable 5
a91be13069
Latest upstream master; the crash-relaunch env leak patch still applies. Co-Authored-By: Claude Fable 5 <noreply@anthropic.com>
80 lines
2.0 KiB
Bash
80 lines
2.0 KiB
Bash
# Maintainer: Entailz <entail-wraps0r at icloud dot com>
|
|
|
|
_pkgname=quickshell
|
|
pkgname="$_pkgname-git"
|
|
pkgver=0.3.0.r18.g10b439f
|
|
pkgrel=2
|
|
pkgdesc='Flexible toolkit for making desktop shells with QtQuick'
|
|
arch=(x86_64 aarch64)
|
|
url='https://git.outfoxxed.me/quickshell/quickshell'
|
|
options=(!strip)
|
|
license=('LGPL-3.0-only')
|
|
depends=(
|
|
'qt6-declarative'
|
|
'qt6-base'
|
|
'jemalloc'
|
|
'qt6-svg'
|
|
'libpipewire'
|
|
'libxcb'
|
|
'wayland'
|
|
'libdrm'
|
|
'mesa'
|
|
'cpptrace'
|
|
'vulkan-headers'
|
|
'polkit'
|
|
)
|
|
makedepends=(
|
|
'spirv-tools'
|
|
'qt6-shadertools'
|
|
'wayland'
|
|
'wayland-protocols'
|
|
'cli11'
|
|
'ninja'
|
|
'cmake'
|
|
'git'
|
|
)
|
|
provides=("$_pkgname")
|
|
conflicts=("$_pkgname")
|
|
|
|
_pkgsrc="$_pkgname"
|
|
source=("$_pkgsrc"::"git+$url.git#commit=10b439fc6e3fd65c15fe1c486271b31da05ed023"
|
|
quickshell-check.hook
|
|
0001-launch-clear-crash-relaunch-env.patch)
|
|
sha256sums=('SKIP'
|
|
'8543e21aeaaa5441b73a679160e7601a957f16c433e8d6bd9257e80bd0e94083'
|
|
'867f154dd3ea09ec751664e84fe9da47f6e0321b77abaa0cf3eb391a978de305')
|
|
|
|
|
|
prepare() {
|
|
cd "$_pkgsrc"
|
|
# After a crash relaunch, quickshell leaks __QUICKSHELL_CRASH_* into the
|
|
# environment of every child it spawns, so any `qs` call from those children
|
|
# boots a duplicate shell instead of running its command.
|
|
# Carried on the fix-crash-env-leak branch of https://github.com/omacom-io/quickshell
|
|
patch -Np1 -i "$srcdir/0001-launch-clear-crash-relaunch-env.patch"
|
|
}
|
|
|
|
pkgver() {
|
|
cd "$_pkgsrc"
|
|
git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
|
|
| sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
|
|
}
|
|
|
|
build() {
|
|
cd "$_pkgname"
|
|
cmake -GNinja -B build \
|
|
-DCMAKE_BUILD_TYPE="RelWithDebInfo" \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DDISTRIBUTOR="AUR (package: quickshell-git)" \
|
|
-DINSTALL_QML_PREFIX=lib/qt6/qml
|
|
|
|
cmake --build build
|
|
}
|
|
|
|
package() {
|
|
install -Dm644 "quickshell-check.hook" -t "$pkgdir/usr/share/libalpm/hooks"
|
|
cd "$_pkgname"
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$_pkgname"
|
|
}
|