Files
omarchy-pkgs/pkgbuilds/omakade/PKGBUILD
T
Emir Beganovic 27b5c480af omakade: update to 1.14.2 and follow upstream's dependencies
Upstream's release PKGBUILD added python (packaged skill scripts, since
1.12.0), layer-shell-qt (a required build dependency for the Game Mode
overlay, since 1.14.0) and the libpulse and umu-launcher optdepends.
The upstream sync only rewrites pkgver and checksums, so the recipe kept
1.12.0's dependency list: the published 1.12.0 lacks python, and the
1.14 builds in the sync PR fail at CMake on LayerShellQt.

The recipe now matches upstream's PKGBUILD-1.14.2, comments aside.
2026-10-04 01:43:34 +02:00

29 lines
1.2 KiB
Bash

pkgname=omakade
pkgver=1.14.2
pkgrel=1
pkgdesc='A beautiful, local-first game library for Omarchy'
arch=('x86_64' 'aarch64')
url='https://btsouth.github.io/omakade/'
license=('GPL-3.0-or-later' 'CC-BY-SA-3.0')
depends=('glib2' 'hicolor-icon-theme' 'layer-shell-qt' 'libsecret' 'libzip' 'openssl' 'python' 'qt6-base' 'qt6-declarative' 'qt6-imageformats' 'qt6-svg' 'qt6-wayland' 'sdl3' 'wayland' 'zstd')
optdepends=('libpulse: switch Game Mode sound outputs with pactl'
'umu-launcher: launch Windows GOG and Proton Battle.net games')
# wayland-protocols turns the optional idle-inhibit feature on
# deterministically instead of leaving it to what the chroot happens to carry.
makedepends=('cmake' 'ninja' 'pkgconf' 'wayland-protocols')
options=('!debug')
source=("$pkgname-$pkgver.tar.gz::https://github.com/btsouth/omakade/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('eaa80d3604ab0d090e3bc958cc8e815b94e3fd1216bf5d478eabccea04aa380d')
build() {
cmake -S "$pkgname-$pkgver" -B build -G Ninja \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DBUILD_TESTING=OFF
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
}