Omabot
ced6963010
Arch shipped qt6-base 6.11.2-2 on 2026-08-20, and the published 0.3.0.r20.g28771c7-1, built against 6.11.1, stopped starting: undefined symbol _ZN23QUntypedPropertyBindingC1EP23QPropertyBindingPrivate, version Qt_6_PRIVATE_API. quickshell-check.hook caught it post-transaction, but detecting is all it does, so pacman logged the failure and omarchy-update-restart went on to restart a shell whose binary could no longer launch.
The git rev has not moved, so the rebuild only reaches anyone through a pkgrel bump. rebuild_on names the three Qt packages quickshell actually links against: qt6-base for Core, Gui, Widgets, Network, DBus and OpenGL, qt6-declarative for Quick and the Qml libraries, qt6-wayland for WaylandClient. rebuilt_against is seeded with the versions this rebuild will link against, so bin/sync-rebuilds starts from a correct baseline and fires on the next Qt release rather than repeating this one.
🤖 Generated by Opus 5 in Claude Code.
68 lines
1.5 KiB
Bash
68 lines
1.5 KiB
Bash
# Maintainer: Entailz <entail-wraps0r at icloud dot com>
|
|
|
|
_pkgname=quickshell
|
|
pkgname="$_pkgname-git"
|
|
pkgver=0.3.0.r20.g28771c7
|
|
pkgrel=2
|
|
pkgdesc='Flexible toolkit for making desktop shells with QtQuick'
|
|
arch=(x86_64 aarch64)
|
|
url='https://git.outfoxxed.me/quickshell/quickshell'
|
|
options=(!strip)
|
|
license=('LGPL-3.0-only')
|
|
depends=(
|
|
'qt6-declarative'
|
|
'qt6-base'
|
|
'jemalloc'
|
|
'qt6-svg'
|
|
'libpipewire'
|
|
'libxcb'
|
|
'wayland'
|
|
'libdrm'
|
|
'mesa'
|
|
'cpptrace'
|
|
'vulkan-headers'
|
|
'polkit'
|
|
)
|
|
makedepends=(
|
|
'spirv-tools'
|
|
'qt6-shadertools'
|
|
'wayland'
|
|
'wayland-protocols'
|
|
'cli11'
|
|
'ninja'
|
|
'cmake'
|
|
'git'
|
|
)
|
|
provides=("$_pkgname")
|
|
conflicts=("$_pkgname")
|
|
|
|
_pkgsrc="$_pkgname"
|
|
source=("$_pkgsrc"::"git+$url.git#commit=28771c7c74b42e20afca0b1b63980cb46515537c"
|
|
quickshell-check.hook)
|
|
sha256sums=('SKIP'
|
|
'8543e21aeaaa5441b73a679160e7601a957f16c433e8d6bd9257e80bd0e94083')
|
|
|
|
pkgver() {
|
|
cd "$_pkgsrc"
|
|
git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
|
|
| sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
|
|
}
|
|
|
|
build() {
|
|
cd "$_pkgname"
|
|
cmake -GNinja -B build \
|
|
-DCMAKE_BUILD_TYPE="RelWithDebInfo" \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DDISTRIBUTOR="AUR (package: quickshell-git)" \
|
|
-DINSTALL_QML_PREFIX=lib/qt6/qml
|
|
|
|
cmake --build build
|
|
}
|
|
|
|
package() {
|
|
install -Dm644 "quickshell-check.hook" -t "$pkgdir/usr/share/libalpm/hooks"
|
|
cd "$_pkgname"
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$_pkgname"
|
|
}
|