David Heinemeier HanssonandClaude Opus 5
bdbf7182c0
The build image sets COMPRESSZST to zstd's default level, which leaves this 1.3 GB Electron tree at 448 MB -- larger than the 334 MB deb it repackages. Maximum zstd brings it to 323 MB, beating xz on both size and decompression speed, for ~4 extra minutes of build time. Carried as an .omarchy patch so it survives AUR syncs. pkgrel picks up the Omarchy suffix accordingly. Co-Authored-By: Claude Opus 5 (1M context) <noreply@anthropic.com>
97 lines
2.5 KiB
Bash
97 lines
2.5 KiB
Bash
# Maintainer: Parsiad Azimzadeh <parsiad.azimzadeh at gmail dot com>
|
|
# Maintainer: mothran
|
|
# Official downloads: https://chatgpt.com/codex/
|
|
|
|
pkgname=openai-codex-desktop
|
|
pkgver=26.803.81509
|
|
pkgrel=8.1
|
|
pkgdesc="Official ChatGPT desktop app with Codex"
|
|
arch=('x86_64' 'aarch64')
|
|
url="https://chatgpt.com/codex/"
|
|
license=('custom')
|
|
|
|
depends=(
|
|
'alsa-lib'
|
|
'at-spi2-core'
|
|
'bash'
|
|
'cairo'
|
|
'dbus'
|
|
'expat'
|
|
'gcc-libs'
|
|
'gdk-pixbuf2'
|
|
'glib2'
|
|
'glibc'
|
|
'gtk3'
|
|
'libcups'
|
|
'libdrm'
|
|
'libglvnd'
|
|
'libnotify'
|
|
'libusb'
|
|
'libx11'
|
|
'libxcb'
|
|
'libxcomposite'
|
|
'libxdamage'
|
|
'libxext'
|
|
'libxfixes'
|
|
'libxkbcommon'
|
|
'libxrandr'
|
|
'mesa'
|
|
'nspr'
|
|
'nss'
|
|
'openssl'
|
|
'pango'
|
|
'systemd-libs'
|
|
'xdg-utils'
|
|
'xz'
|
|
)
|
|
|
|
optdepends=(
|
|
'apparmor: load the bundled user-namespace profile on AppArmor systems'
|
|
'git: version control integration'
|
|
)
|
|
|
|
makedepends=('libarchive')
|
|
provides=('chatgpt')
|
|
conflicts=('chatgpt')
|
|
options=('!debug' '!strip')
|
|
|
|
# Omarchy: the build image compresses with zstd at its default level, which
|
|
# leaves this 1.3 GB Electron tree at 447 MB. Maximum zstd takes it to 322 MB
|
|
# for ~4 extra minutes of build time -- worth it for a package this large that
|
|
# every user re-downloads on each of OpenAI's frequent releases.
|
|
COMPRESSZST=(zstd -c -z -q --ultra -22 --threads=0 -)
|
|
|
|
_deb_x86_64="chatgpt_${pkgver}_amd64.deb"
|
|
_deb_aarch64="chatgpt_${pkgver}_arm64.deb"
|
|
source=('chatgpt-launcher.sh')
|
|
source_x86_64=(
|
|
"${_deb_x86_64}::https://persistent.oaistatic.com/codex-app-prod/linux/deb/latest/chatgpt_amd64.deb"
|
|
)
|
|
source_aarch64=(
|
|
"${_deb_aarch64}::https://persistent.oaistatic.com/codex-app-prod/linux/deb/latest/chatgpt_arm64.deb"
|
|
)
|
|
noextract=("${_deb_x86_64}" "${_deb_aarch64}")
|
|
sha256sums=('4e3ca9302600bed268f8fd3ba2c9ac2f1ceb99da139ed71c50db0289b118d06f')
|
|
sha256sums_x86_64=('a9bf91a368f9f7c4eea38082a9fb8fb46b8d005b719a6d7715d2e5a1982c38eb')
|
|
sha256sums_aarch64=('f38fcc194eca9ab0327dc10c92340681eae77c5d75164df700384ce2adaccbc1')
|
|
|
|
package() {
|
|
cd "${srcdir}"
|
|
|
|
local deb_var="_deb_${CARCH}"
|
|
local deb="${!deb_var}"
|
|
|
|
bsdtar -xOf "${deb}" data.tar.xz |
|
|
bsdtar --no-same-owner -xf - -C "${pkgdir}"
|
|
|
|
rm "${pkgdir}/usr/bin/chatgpt"
|
|
install -Dm755 chatgpt-launcher.sh "${pkgdir}/usr/bin/chatgpt"
|
|
ln -s chatgpt "${pkgdir}/usr/bin/codex-desktop"
|
|
|
|
install -Dm644 "${pkgdir}/usr/share/doc/chatgpt/copyright" \
|
|
"${pkgdir}/usr/share/licenses/${pkgname}/copyright"
|
|
|
|
# Debian package-policy files are not used on Arch Linux.
|
|
rm -rf "${pkgdir}/usr/share/doc" "${pkgdir}/usr/share/lintian"
|
|
}
|