omarchy/default/plymouth/omarchy.script

# Omarchy Plymouth Theme Script

Window.SetBackgroundTopColor(0.101, 0.105, 0.149);
Window.SetBackgroundBottomColor(0.101, 0.105, 0.149);

logo.image = Image("logo.png");
logo.sprite = Sprite(logo.image);
logo.sprite.SetOpacity(1);

# Use these to adjust the progress bar timing
global.fake_progress_limit = 0.7;  # Target percentage for fake progress (0.0 to 1.0)
global.fake_progress_duration = 15.0;  # Duration in seconds to reach limit

# Progress bar animation variables
global.animation_frame = 0;
global.fake_progress = 0.0;
global.real_progress = 0.0;
global.fake_progress_active = 0;
global.fake_progress_start_time = 0.0;  # Track when fake progress started
global.password_shown = 0;  # Track if password dialog has been shown
global.max_progress = 0.0;  # Track the maximum progress reached to prevent backwards movement

# Window size the sprites were last laid out for
global.layout_width = 0;
global.layout_height = 0;

fun refresh_callback() {
  # Displays can show up after this script ran, e.g. a Thunderbolt monitor
  # whose DisplayPort tunnel comes up after plymouthd started. The window
  # grows to the largest display, so re-center everything when it changes.
  if (Window.GetWidth() != global.layout_width || Window.GetHeight() != global.layout_height) {
    layout();
  }

  global.animation_frame++;

  # Animate fake progress to limit over time with easing
  if (global.fake_progress_active == 1) {
    # Calculate elapsed time since start
    elapsed_time = global.animation_frame / 50.0;  # Convert frames to seconds (50 FPS)

    # Calculate linear progress ratio (0 to 1) based on time
    time_ratio = elapsed_time / global.fake_progress_duration;
    if (time_ratio > 1.0) time_ratio = 1.0;

    # Apply easing curve: ease-out quadratic
    # Formula: 1 - (1 - x)^2
    eased_ratio = 1 - ((1 - time_ratio) * (1 - time_ratio));

    # Calculate fake progress based on eased ratio
    global.fake_progress = eased_ratio * global.fake_progress_limit;

    # Update progress bar with fake progress
    update_progress_bar(global.fake_progress);
  }
}

Plymouth.SetRefreshFunction(refresh_callback);

#----------------------------------------- Helper Functions --------------------------------

fun update_progress_bar(progress) {
  # Only update if progress is moving forward
  if (progress > global.max_progress) {
    global.max_progress = progress;

    width = Math.Int(progress_bar.original_image.GetWidth() * progress);
    if (width < 1) width = 1;  # Ensure minimum width of 1 pixel

    progress_bar.image = progress_bar.original_image.Scale(width, progress_bar.original_image.GetHeight());
    progress_bar.sprite.SetImage(progress_bar.image);
  }
}

fun show_progress_bar() {
  progress_box.sprite.SetOpacity(1);
  progress_bar.sprite.SetOpacity(1);
}

fun hide_progress_bar() {
  progress_box.sprite.SetOpacity(0);
  progress_bar.sprite.SetOpacity(0);
}

fun show_password_dialog() {
  lock.sprite.SetOpacity(1);
  entry.sprite.SetOpacity(1);
}

fun hide_password_dialog() {
  lock.sprite.SetOpacity(0);
  entry.sprite.SetOpacity(0);

  for (index = 0; bullet.sprites[index]; index++) {
    bullet.sprites[index].SetOpacity(0);
  }
}

fun start_fake_progress() {
  global.fake_progress_active = 1;

  # Reset fake progress
  global.animation_frame = 0;
  global.max_progress = 0.0;
  global.fake_progress = 0.0;
  global.fake_progress_start_time = 0.0;
}

fun stop_fake_progress() {
  global.fake_progress_active = 0;
}

#----------------------------------------- Dialogue --------------------------------

lock.image = Image("lock.png");
entry.image = Image("entry.png");
bullet.image = Image("bullet.png");

entry.sprite = Sprite(entry.image);
entry.sprite.SetOpacity(0);

# Scale lock to be slightly shorter than entry field height
# Original lock is 84x96, entry height determines scale
lock.height = entry.image.GetHeight() * 0.8;
lock.width = 84 * (lock.height / 96);

lock.sprite = Sprite(lock.image.Scale(lock.width, lock.height));
lock.sprite.SetOpacity(0);

# Bullet array
bullet.sprites = [];

fun position_bullet(index) {
  bullet.sprites[index].SetPosition(entry.x + 20 + index * (7 + 5), entry.y + entry.image.GetHeight() / 2 - 3.5, 10002);
}

fun display_normal_callback() {
  hide_password_dialog();

  # Get current mode
  mode = Plymouth.GetMode();

  # Only show progress bar for boot and resume modes
  if ((mode == "boot" || mode == "resume") && global.password_shown == 1) {
    show_progress_bar();
    start_fake_progress();
  }
}

fun display_password_callback(prompt, bullets) {
  global.password_shown = 1;  # Mark that password dialog has been shown

  # Stop fake progress when password dialog appears
  stop_fake_progress();
  hide_progress_bar();
  show_password_dialog();

  # Clear all bullets first
  for (index = 0; bullet.sprites[index]; index++) {
    bullet.sprites[index].SetOpacity(0);
  }

  # Create and show bullets for current password (max 21)
  max_bullets = 21;
  bullets_to_show = bullets;
  if (bullets_to_show > max_bullets) {
    bullets_to_show = max_bullets;
  }

  for (index = 0; index < bullets_to_show; index++) {
    if (!bullet.sprites[index]) {
      # Scale bullet image to 7x7 pixels
      bullet.sprites[index] = Sprite(bullet.image.Scale(7, 7));
      position_bullet(index);
    }

    bullet.sprites[index].SetOpacity(1);
  }
}

Plymouth.SetDisplayNormalFunction(display_normal_callback);
Plymouth.SetDisplayPasswordFunction(display_password_callback);

#----------------------------------------- Progress Bar --------------------------------

progress_box.image = Image("progress_box.png");
progress_box.sprite = Sprite(progress_box.image);
progress_box.sprite.SetOpacity(0);

progress_bar.original_image = Image("progress_bar.png");
progress_bar.sprite = Sprite();
progress_bar.image = progress_bar.original_image.Scale(1, progress_bar.original_image.GetHeight());
progress_bar.sprite.SetOpacity(0);

fun progress_callback(duration, progress) {
  # Track when fake progress starts
  # Needed because duration and progress freeze during drive decryption
  if (global.fake_progress_start_time == 0.0) {
    global.fake_progress_start_time = duration;
  }

  global.real_progress = progress;

  # Use real progress once its unfrozen and exceeds fake progress
  if (duration > global.fake_progress_start_time && progress > global.fake_progress) {
    stop_fake_progress();
    update_progress_bar(progress);
  }
}

Plymouth.SetBootProgressFunction(progress_callback);

#----------------------------------------- Layout --------------------------------

# Center the logo, dialogue and progress bar for the current window size
fun layout() {
  global.layout_width = Window.GetWidth();
  global.layout_height = Window.GetHeight();

  logo.sprite.SetX(global.layout_width / 2 - logo.image.GetWidth() / 2);
  logo.sprite.SetY(global.layout_height / 2 - logo.image.GetHeight() / 2);

  entry.x = global.layout_width / 2 - entry.image.GetWidth() / 2;
  entry.y = logo.sprite.GetY() + logo.image.GetHeight() + 40;
  entry.sprite.SetPosition(entry.x, entry.y, 10001);

  lock.x = entry.x - lock.width - 15;
  lock.y = entry.y + entry.image.GetHeight() / 2 - lock.height / 2;
  lock.sprite.SetPosition(lock.x, lock.y, 10001);

  for (index = 0; bullet.sprites[index]; index++) {
    position_bullet(index);
  }

  progress_box.x = global.layout_width / 2 - progress_box.image.GetWidth() / 2;
  progress_box.y = entry.y + entry.image.GetHeight() / 2 - progress_box.image.GetHeight() / 2;
  progress_box.sprite.SetPosition(progress_box.x, progress_box.y, 0);

  progress_bar.x = global.layout_width / 2 - progress_bar.original_image.GetWidth() / 2;
  progress_bar.y = progress_box.y + (progress_box.image.GetHeight() - progress_bar.original_image.GetHeight()) / 2;
  progress_bar.sprite.SetPosition(progress_bar.x, progress_bar.y, 1);
}

layout();

#----------------------------------------- Message --------------------------------

message_sprite = Sprite();
message_sprite.SetPosition(10, 10, 10000);

fun display_message_callback(text) {
  message = Image.Text(text, 1, 1, 1);
  message_sprite.SetImage(message);
  message_sprite.SetOpacity(1);
}

fun hide_message_callback(text) {
  message_sprite.SetOpacity(0);
}

Plymouth.SetDisplayMessageFunction(display_message_callback);
Plymouth.SetHideMessageFunction(hide_message_callback);