Maintain a herdr fork until we can get upstream feature changes

pkgbuilds/omarchy-herdr/.omarchy/package.json

@@ -0,0 +1,3 @@
+{
+  "source": "local"
+}

pkgbuilds/omarchy-herdr/PKGBUILD

@@ -0,0 +1,45 @@
+# Maintainer: David Heinemeier Hansson <david@hey.com>
+
+pkgname=omarchy-herdr
+pkgver=0.8.0.r1
+pkgrel=1
+pkgdesc="Herdr terminal workspace manager with Omarchy pane border support"
+arch=('x86_64' 'aarch64')
+url="https://github.com/dhh/herdr"
+license=('Apache-2.0')
+depends=('gcc-libs' 'glibc')
+makedepends=('cargo')
+provides=('herdr')
+conflicts=('herdr')
+options=('!debug' '!lto')
+
+_commit=50fc0567049b0e006e52987fbd5cb159b655c452
+_zigver=0.15.2
+source=("herdr-$_commit.tar.gz::$url/archive/$_commit.tar.gz")
+source_x86_64=("zig-x86_64-linux-$_zigver.tar.xz::https://ziglang.org/download/$_zigver/zig-x86_64-linux-$_zigver.tar.xz")
+source_aarch64=("zig-aarch64-linux-$_zigver.tar.xz::https://ziglang.org/download/$_zigver/zig-aarch64-linux-$_zigver.tar.xz")
+sha256sums=('08010fddea3b438f9fc337d3e50f7438fa91b452ab712ed72144d511e2aa2f0f')
+sha256sums_x86_64=('02aa270f183da276e5b5920b1dac44a63f1a49e55050ebde3aecc9eb82f93239')
+sha256sums_aarch64=('958ed7d1e00d0ea76590d27666efbf7a932281b3d7ba0c6b01b0ff26498f667f')
+
+prepare() {
+  cd "herdr-$_commit"
+
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "herdr-$_commit"
+
+  export CARGO_TARGET_DIR=target
+  export ZIG="$srcdir/zig-$CARCH-linux-$_zigver/zig"
+  export ZIG_GLOBAL_CACHE_DIR="$srcdir/zig-cache"
+  cargo build --frozen --release
+}
+
+package() {
+  cd "herdr-$_commit"
+
+  install -Dm755 target/release/herdr "$pkgdir/usr/bin/herdr"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}