Add retroarch-joypad-autoconfig-git for preconfigured joypads

2026-05-04 17:30:21 +02:00
parent ad9e338956
commit 6b99f777df
3 changed files with 52 additions and 0 deletions
@@ -30,6 +30,7 @@ nautilus-open-any-terminal
 once-bin
 pinta
 python-terminaltexteffects
+retroarch-joypad-autoconfig-git
 ttf-ia-writer
 typora
 tzupdate
@@ -0,0 +1,16 @@
+pkgbase = retroarch-joypad-autoconfig-git
+	pkgdesc = RetroArch joypad autoconfig files
+	pkgver = 1.22.0.r24.g739cee1
+	pkgrel = 1
+	url = https://github.com/libretro/retroarch-joypad-autoconfig
+	arch = any
+	groups = libretro
+	license = MIT
+	makedepends = git
+	optdepends = retroarch
+	provides = retroarch-joypad-autoconfig
+	conflicts = retroarch-joypad-autoconfig
+	source = retroarch-joypad-autoconfig::git+https://github.com/libretro/retroarch-joypad-autoconfig.git
+	b2sums = SKIP
+
+pkgname = retroarch-joypad-autoconfig-git
@@ -0,0 +1,35 @@
+# Maintainer: Alexandre Bouvier <contact@amb.tf>
+_pkgname=retroarch-joypad-autoconfig
+pkgname=$_pkgname-git
+pkgver=1.22.0.r24.g739cee1
+pkgrel=1
+pkgdesc="RetroArch joypad autoconfig files"
+arch=('any')
+url="https://github.com/libretro/retroarch-joypad-autoconfig"
+license=('MIT')
+groups=('libretro')
+makedepends=('git')
+optdepends=('retroarch')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=("$_pkgname::git+$url.git")
+b2sums=('SKIP')
+
+pkgver() {
+	cd $_pkgname
+	git describe --long --tags --abbrev=7 | sed 's/^v//;s/[^-]*-g/r&/;s/-/./g'
+}
+
+prepare() {
+	cd $_pkgname
+	# remove non-linux drivers
+	rm -r dinput mfi qnx xinput
+}
+
+package() {
+	cd $_pkgname
+	# shellcheck disable=SC2154
+	find . -iname '*.cfg' -type f -exec install -Dm644 {} "$pkgdir"/usr/share/libretro/autoconfig/{} \;
+	install -Dm644 -t "$pkgdir"/usr/share/doc/$pkgname README.md retropad_layout.png
+	install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname COPYING
+}