Add Task Manager for Omarchy 0.0.3 preview

pkgbuilds/omarchy-task-manager/.omarchy/package.json

@@ -0,0 +1,11 @@
+{
+  "source": "local",
+  "channels": ["edge"],
+  "upstream": {
+    "watch": {
+      "github": "tcballard/omarchy-task-manager",
+      "pattern": "v(?P<version>[0-9]+\\.[0-9]+\\.[0-9]+)",
+      "allow_prerelease": true
+    }
+  }
+}

pkgbuilds/omarchy-task-manager/PKGBUILD

@@ -0,0 +1,33 @@
+# Canonical recipe. scripts/package-source.sh fills the release source checksum.
+# Maintainer: Tom Ballard (tcballard)
+pkgname=omarchy-task-manager
+pkgver=0.0.3
+pkgrel=1
+url='https://github.com/tcballard/omarchy-task-manager'
+pkgdesc='Floating native task manager for Omarchy (preview)'
+arch=('x86_64')
+license=('MIT')
+depends=('qt6-base' 'qt6-declarative' 'qt6-wayland' 'qt6-svg' 'hicolor-icon-theme' 'gcc-libs' 'glibc' 'glib2' 'systemd' 'coreutils')
+optdepends=('gdb: live process core dumps' 'nvidia-utils: NVIDIA device telemetry')
+makedepends=('cmake' 'ninja' 'rust' 'cargo')
+checkdepends=('python' 'desktop-file-utils')
+source=("$url/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('cc3e24a0bb8fad2b7ce0d4fb780aa774d32b53b8de924b488b55674bdb936c85')
+
+build() {
+  cmake -S "$srcdir/$pkgname-$pkgver" -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_INSTALL_LIBDIR=lib
+  cmake --build build
+}
+
+check() {
+  cd "$srcdir/$pkgname-$pkgver"
+  cargo test --locked
+  ctest --test-dir "$srcdir/build" --output-on-failure
+  desktop-file-validate packaging/io.github.tcballard.TaskManager.desktop
+  python tests/protocol.py "$srcdir/build/omarchy-task-manager-core"
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}