Added Omacut 0.1.0

2026-06-22 17:08:17 +02:00
parent ba0292e4cb
commit fb52a78761
3 changed files with 57 additions and 0 deletions
@@ -0,0 +1,3 @@
+{
+  "source": "local"
+}
@@ -0,0 +1,42 @@
+# Maintainer: David Heinemeier Hansson <david@hey.com>
+
+pkgname=omacut
+pkgver=0.1.0
+pkgrel=1
+pkgdesc='Dead-simple video length trimmer built with Qt Quick and ffmpeg'
+arch=('x86_64' 'aarch64')
+url='https://github.com/omacom-io/omacut'
+license=('MIT')
+install='omacut.install'
+options=('!debug')
+depends=(
+  'ffmpeg'
+  'hicolor-icon-theme'
+  'qt6-base'
+  'qt6-declarative'
+  'qt6-multimedia'
+  'xdg-desktop-portal'
+)
+makedepends=(
+  'gcc'
+  'make'
+  'qt6-base'
+  'qt6-declarative'
+  'qt6-multimedia'
+)
+source=("$pkgname-$pkgver.tar.gz::https://github.com/omacom-io/omacut/archive/refs/tags/v$pkgver.tar.gz")
+sha256sums=('8ec4f57ac75b24517d6b6b9b95712c047c117e0c8ca99e6a6a04391e790fae74')
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+  ./bin/build
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  install -Dm755 build/omacut "$pkgdir/usr/bin/omacut"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm644 pkgbuild/omacut.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/omacut.svg"
+  install -Dm644 pkgbuild/omacut.desktop "$pkgdir/usr/share/applications/omacut.desktop"
+}
@@ -0,0 +1,12 @@
+post_install() {
+  command -v update-desktop-database >/dev/null 2>&1 && update-desktop-database -q
+  command -v gtk-update-icon-cache >/dev/null 2>&1 && gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}